Progression4が正式リリースされたので、3で使用していたローダーを4に移植しました。
サンプル01
サンプル02
サンプル03

使い方は下記からソースコードをダウンロードし、
解凍してできた「Preloader.as」と「LoaderCommand.as」を
Progression4プロジェクトを作成した際にできる「src」フォルダに上書きし
あとは色や線の太さなどを自由に変えていただければと思います。

また、今回フォント「04b25」を使用しています。
異なるフォントや、埋め込みフォントを使用しない場合。

コンパイルしてもフォントが表示されない場合は以下を調整していただければ問題ないかと思います。

//フォント名を変更
format.font = "04b25";

//この部分を削除
_textField.embedFonts = true;

サンプル01ソースファイル:src.zip
サンプル02ソースファイル:src.zip
サンプル03ソースファイル:src.zip
ドーナッツ型を描画するクラスは「詳細Actionscript3.0 入門ノート」に掲載されているものを使用しています。

Flasplayer10で

	container.addChild(castSprite);

をおこなって、リロードを何度かしていると

と起こられてしまいます。
もちろんaddChildAtなどは使用していません。
Progression3でもおこるようなのですが、3では起こったことがなかったのでなぞです。

応急処置的には

	new AddChildAt(container, castSprite ,container.numChildren),

で起こらなくなりそうです。
ん～～なぞ。。。

参考：
http://www.infective.jp/blog/2009/09/progresssion4.html
http://forum.progression.jp/index.php?topic=33.0

大型店舗ではむつかしい、きめ細かいサービスで、ゆっくりと丁寧に接客をしていただけます。何より、話やすいです。人見知り激しい私でもなんだか普通に話せました。。。なんでだろ？シャンプーでカユイとことがあっても言えない方は是非とも足を運んでみてください。めっちゃたのしいですよ。
http://havana-stripe.com/

3D空間を扱うときはあまり（？）3D空間に急に物体が現れることはないと思ったので
今回はシングルトンクラス内でオブジェクトを生成してみた。
なぜかクリック処理までシングルトン内にあるのでやっぱりオブジェクトの生成は
progressionでやるほうがよいのかな。
なにわともあれもう少し小奇麗にしたい。

使い方は
progressionのIndexScenシーンなりで
SingletonPv3d.getInstance();
_onLoad　や　_onInit内でaddChildしてあげればよいだけ。

あとレンダリングはコンストラクタで行うと
マウスカーソルがチカチカする；
どうしてかな。。。。？

サンプル

ソースコードはこんな感じ。

今きづいたけど、シーン移動中にPlaneをクリックすると
クリックしたシーンに移動してないな。
やっぱりprogression側でカメラの移動したほうが綺麗かも。。
うーん、でもねむいのでまたにする。

SingletonPv3d.as

	public class SingletonPv3d extends Sprite
	{
		static private var _instance:SingletonPv3d;
		private var plane:Plane;
		private var basicBiew:BasicView;
		private var world:DisplayObject3D;
		private var planeCollection:/*DisplayObject3D*/Array;
		private var progression:Progression;

		public function SingletonPv3d(singletonEnforcer:SingletonEnforcer)
		{
			if (singletonEnforcer == null) {
				throw Error("++++SingletonPv3d ERROR!!++++");
			}
		}

		public static function getInstance():SingletonPv3d
		{
			if (!SingletonPv3d._instance)
			{
				SingletonPv3d._instance = new SingletonPv3d(new SingletonEnforcer());
				_instance.drawWorld();

			}
			return SingletonPv3d._instance;
		}

		public function aaaa():void {
			drawWorld();
		}

		private function drawWorld():void
		{
			～～～省略～～～
			//--------------------------------------------------------------------------
			//  basic biewの作成
			//--------------------------------------------------------------------------
			basicBiew = new BasicView(500,500,true,true,"Target");
			addChild(basicBiew);

			//  カメラの設定
			//  オブジェクトの作成などを行う
			～～～省略～～～

			/// イベント処理
			basicBiew.addEventListener(Event.ADDED_TO_STAGE, onStage);

		}

		/// 配置待ち
		private function onStage(e:Event):void
		{
			progression = getProgressionById("index");
			basicBiew.removeEventListener(Event.ADDED_TO_STAGE, onStage);
		}

		/// basicBiew
		public function getBasicBiew():BasicView{return basicBiew;}

		/// world
		public function getWorld():DisplayObject3D{return world;}

		/// camera
		public function getCamera():CameraObject3D{return basicBiew.camera;}

		/// objectの取得
		public function getCollection():Array{return planeCollection;}

		public function startRendering():void{basicBiew.startRendering();}

	}
}

class SingletonEnforcer { }

IndexScene.as

/**
 * コンストラクタ
 */
public function IndexScene() {
	// ブラウザ同期時に出力したいタイトルを設定します。
	//title = "MyProject_2";

	/// シーンを作成
	var n:int = 40;
	for (var i:int = 1; i < n; i++)
	{
		var scene:MyScene = new MyScene(String(i));
		addScene(scene);
	}

	/// シングルトンクラスでPV3Dの3Dシーンを作成
	singletonPv3d = SingletonPv3d.getInstance();

}

/**
 * シーン移動時に目的地がシーンオブジェクト自身もしくは子階層だった場合に、階層が変更された瞬間に送出されます。
 * このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
 */
protected override function _onLoad():void {
	// 実行したいコマンドを登録します。

	/// PV3DをprogressionにAddChildする
	progression.container.addChild(singletonPv3d);

	/// PV3Dのレンダリングを開始
	singletonPv3d.startRendering();

	addCommand(

	);
}

最後になりますが、ソースコード一式あげておきます。
MySceneクラスにBallとか変なクラスあるので削除してお使いください。
サンプル　sauce一式

できたのは　こんな感じ。まんまですね。。
swfそのまま開きます。
http://miraigyo.com/blog/contents/swf/loader1/preloader.swf
そーすは以前とほぼ同じです。

Preloader.as

package myproject {
	import flash.display.StageAlign;
	import flash.display.StageQuality;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.trace.Trace;
	import jp.progression.casts.*;
	import jp.progression.commands.*;
	import jp.progression.core.debug.Verbose;
	import jp.progression.events.*;
	import jp.progression.loader.*;
	import jp.progression.*;
	import jp.progression.scenes.*;
	import ore.graphic.Ball;
	import flash.text.TextFieldAutoSize;

	/**
	 * Preloader クラス
	 */
	public class Preloader extends CastPreloader {
		private var stageW:Number;
		private var stageH:Number;
		private var innnerBall:Ball;
		private var ball:Ball;
		private var txt:TextField;
		private var num:Number = 0;
		public static var flag:int = 0;
		private var parsetage:Number = 0;
		private var loadNum:Number = 0;

		/**
		 * コンストラクタ
		 */
		public function Preloader() {
			// 読み込みたい SWF ファイルの URL を設定します。
			url = "index.swf";

			// SWF ファイルの URL の起点を、自身の SWF ファイルが存在するフォルダにするかどうかを指定します。
			useSWFBasePath = false;
		}

		/**
		 * SWF ファイルの読み込みが完了し、stage 及び loaderInfo にアクセス可能になった場合に送出されます。
		 */
		protected override function _onInit():void {
			// stage の初期設定を行います。
			align = StageAlign.TOP_LEFT;
			quality = StageQuality.HIGH;
			scaleMode = StageScaleMode.NO_SCALE;

			// 開発者用の出力を有効化します。
			//Verbose.enabled = true;
			//Verbose.filteringCommand();

			stageW = stage.stageWidth;
			stageH = stage.stageHeight;

			ball = new Ball(40, 0x36362C);
			ball.scaleX = 0;
			ball.scaleY = 0;
			ball.alpha = 0;
			ball.x = stageW/2;
			ball.y = stageH/2;
			addChild(ball);

			innnerBall = new Ball(40,0xA8AD80);
			innnerBall.x = stageW/2;
			innnerBall.y = stageH / 2;
			innnerBall.scaleX = 0;
			innnerBall.scaleY = 0;
			addChild(innnerBall);

			var format:TextFormat = new TextFormat();
			format.font = "Arial";

			txt = new TextField();
			txt.autoSize = TextFieldAutoSize.CENTER;
			txt.appendText("0%");
			txt.x = stageW / 2-txt.width/2;
			txt.y = stageH / 2 - txt.height / 2;
			txt.embedFonts = true;
			txt.defaultTextFormat = format;
			txt.textColor = 0xffffff;
			addChild(txt)
		}

		/**
		 * オブジェクトが読み込みを開始した瞬間に送出されます。
		 * このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
		 */
		protected override function _onCastLoadStart():void {
			// 実行したいコマンドを登録します。
			addCommand(
				new DoTweener(ball, {
					alpha:1,
					scaleX:1,
					scaleY:1,
					time:0.6
				})
			);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);

		}

		/**
		 * ダウンロード処理を実行中にデータを受信したときに送出されます。
		 */
		protected override function _onProgress():void {
			loadNum = bytesLoaded / bytesTotal;
		}

		/**
		 * オブジェクトが読み込みを完了した瞬間に送出されます。
		 * このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
		 */
		protected override function _onCastLoadComplete():void {
			// 実行したいコマンドを登録します。
			var comnd:LoaderCommand = new LoaderCommand();

			addCommand(
				comnd,
				[
				new DoTweener(ball, {
					alpha:0,
					scaleX:1.5,
					scaleY:1.5,
					time:1
				}),

				new DoTweener(innnerBall, {
					scaleX:0,
					scaleY:0,
					time:1
				}),

				new DoTweener(txt, {
					alpha:0,
					time:1
				})

				]
			);
		}

		//////////////////////////////////////////////////////////////////////////////////////////////////////////////
		///  ローダーのあにめーしょん
		//////////////////////////////////////////////////////////////////////////////////////////////////////////////
		private function onEnterFrame(e:Event):void
		{

			parsetage += (loadNum - parsetage) * 0.2;
			innnerBall.scaleX = parsetage;
			innnerBall.scaleY = parsetage;
			txt.text = String(Math.floor(parsetage*100))+"%";
			if (parsetage > 0.98) {
				txt.text = "100%";
				stage.removeEventListener(Event.ENTER_FRAME, onEnterFrame);
				flag = 1;
			}
		}

		//////////////////////////////////////////////////////////////////////////////////////////////////////////////
		/// flag getter
		//////////////////////////////////////////////////////////////////////////////////////////////////////////////
		public static function get getFlag():int {
			return flag;
		}
	}
}

LoaderCommand.as

package myproject{
	import jp.progression.casts.*;
	import jp.progression.commands.*;
	import jp.progression.core.commands.Command;
	import jp.progression.events.*;
	import jp.progression.loader.*;
	import jp.progression.*;
	import jp.progression.scenes.*;

	import flash.utils.Timer;
	import flash.events.TimerEvent;
	import flash.events.Event;

	/**
	 * MyCommand クラス
	 */
	public class LoaderCommand extends Command {

		private var _returnValue:String;
		private var timer:Timer;
		private var flag:int;

		/**
		 * コンストラクタ
		 */
		public function LoaderCommand( initObject:Object = null ) {
			super( _execute, _interrupt, initObject );
		}

		/**
		 * 実行されるコマンドの実装です。
		 */
		private function _execute():void {
			// 通常処理を終了します。
			timer = new Timer(100);
			timer.addEventListener(TimerEvent.TIMER, onTime);
			timer.start();

		}

		private function onTime(e:TimerEvent):void
		{
			flag = Preloader.getFlag;

			if(flag == 1){
				executeComplete();
				timer.removeEventListener(TimerEvent.TIMER, onTime);
			}
		}

		/**
		 * 中断実行されるコマンドの実装です。
		 */
		private function _interrupt():void {
			// 中断処理を終了します。
			interruptComplete();
		}

		/**
		 * MyCommand インスタンスのコピーを作成して、各プロパティの値を元のプロパティの値と一致するように設定します。
		 */
		public override function clone():Command {
			return new LoaderCommand( this );
		}

		public function get returnValue():String {
			return _returnValue;
		}
	}
}

きっと簡単になめらかにできると思うとなんだか右往左往しながら制作してしまったのでメモ。しかも、このやり方がとても周りくどいと思うので、どなたか簡単に実装できる方法などございましたら、ご連絡いただければ幸いです。

まずはローディングバーを作成

protected override function _onCastLoadStart():void {
    // 実行したいコマンドを登録します。

    /************************************************************************
    *　テキストフォーマット＆テキストエリア
    ************************************************************************/

    txt = new TextField();
    txt.autoSize = TextFieldAutoSize.RIGHT;
    txt.x = stage.stageWidth-10;
    txt.y = stage.stageHeight / 2-150;
    txt.appendText("0%");
    addChild(txt);

    /************************************************************************
    *　ローディングバーの作成
    ************************************************************************/
    barbar = new Sprite();
    with (barbar) {
        graphics.beginFill(0x000000);
        graphics.drawRect(0, -1, 1, 2);
        graphics.endFill();
    }
    barbar.y = stage.stageHeight / 2;
    addChild(barbar);

    //カクカクなるのでエンターフレームで処理をする
    stage.addEventListener(Event.ENTER_FRAME, onEnterFram);

}

ローディングバーのアニメーション

private function onEnterFram(e:Event):void
{

	//読み込んだバイト数の0.1を加算していく
	persentage += (loadbyte - persentage) * 0.1;

	//バーの長さをステージの長さにする
	barbar.width = stage.stageWidth * persentage * 0.01;

	txt.text =  Math.floor(persentage) + "%";

	//100%に近くなったら100にして終了
	if (persentage > 99.5) {
		persentage = 100;
		txt.text =  Math.floor(persentage) + "%";
		barbar.width = stage.stageWidth * persentage * 0.01;

		stage.removeEventListener(Event.ENTER_FRAME, onEnterFram);

		//フラグを0にしてカスタムコマンドを終了
		flag = 0;
	}
}

最後に_onCastLoadComplete()内に終了処理を書けば終わりなのですが、
アニメーションが終わるまで待ってくれない。。。

どうしたものかと検索しているとカスタムコマンドでなんとかなりそうなのが判明。下記サイトを参考に待機処理のコマンドをつくってみる。

• http://web.r-studio.jp/flash/articles/progression_extension_study_in_mtl.html

MyCommand.asを作成し_execute()内を書き換える。
Preloader.asにあるflagを監視することで待機させる方法をとりました。

private function _execute():void
{
	// 通常処理を終了します。
	//_returnValue = "カスタムコマンドだよ！！！！！！"
	timer = new Timer(100);
	timer.addEventListener(TimerEvent.TIMER, onTime);
	timer.start();
	//こいつが終了を通知してくれる。
	//executeComplete();

}

private function onTime(e:TimerEvent):void
{
	//trace("タイマー作動中");　flagの確認
	if(Preloader.flag == 0){
		executeComplete();
		//trace("timerSTOP!!");
		timer.removeEventListener(TimerEvent.TIMER, onTime);
	}
}

最後にPreloader.asの_onCastLoadComplete()内で先ほどのコマンドを呼び出して待機させてばOKでした
呼び出しはこんな感じです。

/**
 * オブジェクトが読み込みを完了した瞬間に送出されます。
 * このイベント処理の実行中には、addCommand() メソッド、及び insertCommand() メソッドによるコマンドの同期処理が行えます。
 */
protected override function _onCastLoadComplete():void {
	// 実行したいコマンドを登録します。

	//コマンドを作成
	var _myCommand:MyCommand = new MyCommand();

	addCommand(
		//new Trace("スタート++++++++++++++++++++"),
		//ここに登録
		_myCommand,

		new DoTweener(txt, {
			alpha:0,
			y:-150,
			time:1.2,
			onComplete:ore
		}),

		new Trace("完了++++++++++++++++++++")
	);
}

こんな感じでなんとかできたのでした。
できたローダーがこんなのです。
もっと簡単にできるような気がする。。。。
説明が分かりにくいので
まとめたソースコードはコチラからダウンロードできます。
ご指摘等いただければ、幸いです。